Ведение адресов

qq

Создал свою таблицу с полем KUNNR и ADRNR (ссылочные соответственно на KNA1 и ADRC). Создал ведение, через генератор ведения таблиц. Удобно, что ведение адресов сразу заработало, но хотелось бы , в случае когда KUNNR заполнен, то чтобы адрес не создавался с нуля, а копировался и адреса дебитора. С полностью ручным ведением я думаю получится, но хотелось бы добится верной работы через генератор ведения. Хотелось бы рекомендаций, а то уже 1 день убил на это.

T

1.Свою таблицу сделай без адреса
2.Создай ракурс ведения для неё, соедини с KNA1 и к списку полей добавь KNA1-ADRNR
3.Сгенерируй ведение к ракурсу
4.В сгенерённом ведении ракурса редактирование адреса будет по кнопке в GUI-статусе

qq

ВаУ. ТОлько написал и сразу сделал

)). Может давно написать надо было?

))
Вообщем пишу на всякий случай. На момент 21(Event 21
Execution : Fill hidden fields) навесил следующий ниже обработчик и все!!!

Code:

FORM YV_ZSD_GU12_KLI_ADR.

  DATA: H_RETURNCODE TYPE AD_RETCODE,
       H_ERROR_TABLE LIKE ADDR_ERROR OCCURS 0,
       H_ADDR1_COMPLETE TYPE SZADR_ADDR1_COMPLETE,
       P_ADRNR LIKE KNA1-ADRNR,
       P_ADDRESS_REFERENCE LIKE ADDR_REF,
       P_HANDLE LIKE SZAD_FIELD-HANDLE.

  IF NOT YV_ZSD_GU12_KLI-KUNNR IS INITIAL
    AND YV_ZSD_GU12_KLI-ADDRNUM IS INITIAL.
    P_HANDLE(15) = YV_ZSD_GU12_KLI.
    SELECT SINGLE ADRNR INTO P_ADRNR
      FROM KNA1 WHERE KUNNR = YV_ZSD_GU12_KLI-KUNNR.
    IF SY-SUBRC = 0.
      CALL FUNCTION 'ADDR_GET_COMPLETE'
           EXPORTING
                ADDRNUMBER              = P_ADRNR
           IMPORTING
                ADDR1_COMPLETE          = H_ADDR1_COMPLETE
           EXCEPTIONS
                PARAMETER_ERROR         = 1
                ADDRESS_NOT_EXIST       = 2
                INTERNAL_ERROR          = 3
                WRONG_ACCESS_TO_ARCHIVE = 4
                OTHERS                  = 5.
      IF SY-SUBRC = 0.
        H_ADDR1_COMPLETE-ADDRHANDLE = P_HANDLE.
        CLEAR: H_ADDR1_COMPLETE-ADDRNUMBER.
        CALL FUNCTION 'ADDR_MAINTAIN_COMPLETE'
             EXPORTING
                  UPDATEFLAG         = 'I'
                  ADDR1_COMPLETE     = H_ADDR1_COMPLETE
                  ADDRESS_GROUP      = 'ZA01'
             IMPORTING
                  ADDR1_COMPLETE_OUT = H_ADDR1_COMPLETE
             EXCEPTIONS
                  PARAMETER_ERROR    = 1
                  ADDRESS_NOT_EXIST  = 2
                  HANDLE_EXIST       = 3
                  INTERNAL_ERROR     = 4
                  OTHERS             = 5.
        IF SY-SUBRC = 0.
          P_ADDRESS_REFERENCE-APPL_TABLE = 'ZSD_GU12'.
          CLEAR P_ADDRESS_REFERENCE-APPL_FIELD.
          P_ADDRESS_REFERENCE-APPL_KEY = P_HANDLE.
          CALL FUNCTION 'ADDR_NUMBER_GET'
               EXPORTING
                    ADDRESS_HANDLE    = H_ADDR1_COMPLETE-ADDRHANDLE
                    ADDRESS_REFERENCE = P_ADDRESS_REFERENCE
               IMPORTING
                    ADDRESS_NUMBER    = YV_ZSD_GU12_KLI-ADDRNUM.
          IF SY-SUBRC = 0.
            CALL FUNCTION 'ADDR_MEMORY_SAVE'
                 EXCEPTIONS
                      ADDRESS_NUMBER_MISSING = 1
                      PERSON_NUMBER_MISSING  = 2
                      INTERNAL_ERROR         = 3
                      DATABASE_ERROR         = 4
                      REFERENCE_MISSING      = 5
                      OTHERS                 = 6.
          ENDIF.
        ENDIF.
      ENDIF.
    ENDIF.
  ENDIF.

ENDFORM.

застопорился на том, что надо было вызвать
CALL FUNCTION 'ADDR_MEMORY_SAVE'

qq

T написал:

1.Свою таблицу сделай без адреса

4.В сгенерённом ведении ракурса редактирование адреса будет по кнопке в GUI-статусе

и где она в этом случае будет хранить ссылку на мой адрес?
или будет редактировать адрес дебитора? Если да, то это не то

T

А, блин, "копировался адрес" - имелось в виду не заполнялось поле ADRNR, а сами адресные данные..
Тогда мой пост не о том..

Правила форума

Ведение адресов

Кто сейчас на конференции