PARAMETERS dummy.

DATA: grid TYPE REF TO cl_gui_alv_grid.
DATA: gt_outtab TYPE TABLE OF t001t.

*---------------------------------------------------------------------*
CLASS lcl_event_receiver DEFINITION.
  PUBLIC SECTION.
    METHODS:
      handle_data_changed
        FOR EVENT data_changed OF cl_gui_alv_grid
          IMPORTING er_data_changed.
ENDCLASS.
*---------------------------------------------------------------------*
CLASS lcl_event_receiver IMPLEMENTATION.
  METHOD handle_data_changed.
    DATA l_ins_row LIKE LINE OF er_data_changed->mt_inserted_rows[].
    LOOP AT er_data_changed->mt_inserted_rows INTO l_ins_row.
      CALL METHOD er_data_changed->modify_cell
        EXPORTING
          i_row_id    = l_ins_row-row_id
          i_fieldname = 'BUKRS'
          i_value     = l_ins_row-row_id
          .
      CALL METHOD er_data_changed->modify_cell
        EXPORTING
          i_row_id    = l_ins_row-row_id
          i_fieldname = 'TXTNA'
          i_value     = 'Новая строка'
          .
    ENDLOOP.
  ENDMETHOD.
ENDCLASS.
*---------------------------------------------------------------------*
DATA: event_receiver TYPE REF TO lcl_event_receiver.

AT SELECTION-SCREEN OUTPUT.
  CHECK grid IS INITIAL.

  CREATE OBJECT grid
    EXPORTING i_parent = cl_gui_container=>default_screen.

  CALL METHOD grid->set_table_for_first_display
    EXPORTING
      i_structure_name = 'T001T'
    CHANGING
       it_outtab = gt_outtab[]
       .

  CALL METHOD grid->set_ready_for_input.

  CREATE OBJECT event_receiver.

  CALL METHOD grid->register_edit_event
    EXPORTING
      i_event_id = cl_gui_alv_grid=>mc_evt_modified.

  SET HANDLER event_receiver->handle_data_changed FOR grid.