Вызов первого экрана

Sent

Подскажите: пишу программу, мне надо сделать, чтобы появляся первый экран. Как это сделать?

ArmAnn

set screen xxxx ?

Виктор(Минск)

Call screen 'XXXX'.?

Sent

Спасибо за помощь. Но у меня еще есть вопросы.

Как активировать кнопку Назад (стрелка влево) и где описывается процедура кнопки "Зелена галочка" (Ввод)?

T

если имеется в виду повторный вызов начального селекционного экрана, то CALL SELECTION-SCREEN 1000.

Sent

Как вывести таблицу в ALV? Имя таблицы здавать в поле на первом экране.

Azik

Мдаааа...... :roll:

Zharik

Чувак, ты видно совсем недавно начал копаться.

Вот посмотри этот код.
Это чтобы не заморачиваться с контейнерами на экранах. Тут немного намутил с фиелдкаталогом - можно было сделать проще. Но работает, а что ещё надо.

* вывод на экран
type-pools: slis.

refresh t_itab .
select * from BNKA into table t_itab.

data:
p_fieldcat type lvc_t_fcat,
l_p_fieldcat type LVC_S_FCAT,
t_fieldcat type SLIS_T_FIELDCAT_ALV,
l_t_fieldcat_ like line of t_fieldcat
.

call function 'LVC_FIELDCATALOG_MERGE'
exporting
i_structure_name = 'BNKA'
changing
ct_fieldcat = p_fieldcat[]
.

LOOP AT p_fieldcat INTO l_p_fieldcat.
move-corresponding l_p_fieldcat TO l_t_fieldcat_.
APPEND l_t_fieldcat_ TO t_fieldcat .
ENDLOOP.

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
I_STRUCTURE_NAME = 'BNKA'
I_BACKGROUND_ID = ' '
I_GRID_TITLE = 'Список банков'
IT_FIELDCAT = t_fieldcat
TABLES
T_OUTTAB = t_itab
.

:twisted:

Наслаждайся

OlegDm

Sent написал(а):

Как вывести таблицу в ALV? Имя таблицы здавать в поле на первом экране.

(C) BH:

Code:

REPORT ZTEST.

TYPE-POOLS: SLIS.

TABLES: DD02L.

DATA: LT_FIELDCAT TYPE SLIS_T_FIELDCAT_ALV,
      LF TYPE LVC_T_FCAT,
      VR TYPE REF TO DATA,
      FC LIKE LINE OF LT_FIELDCAT,
      LFC LIKE LINE OF LF.
      
DATA: G_EXIT_CAUSED_BY_CALLER,
      GS_EXIT_CAUSED_BY_USER TYPE SLIS_EXIT_BY_USER.
      
FIELD-SYMBOLS: <P> TYPE STANDARD TABLE.

PARAMETERS: TABN LIKE DD02L-TABNAME.


CLEAR DD02L.
SELECT SINGLE * FROM DD02L WHERE TABNAME = TABN.

IF NOT DD02L-TABNAME IS INITIAL.

  CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'
       EXPORTING
            I_STRUCTURE_NAME       = TABN
       CHANGING
            CT_FIELDCAT            = LT_FIELDCAT
       EXCEPTIONS
            INCONSISTENT_INTERFACE = 1
            PROGRAM_ERROR          = 2.
  LOOP AT LT_FIELDCAT INTO FC.
    MOVE-CORRESPONDING FC TO LFC.
    APPEND LFC TO LF.
  ENDLOOP.

  CALL METHOD CL_ALV_TABLE_CREATE=>CREATE_DYNAMIC_TABLE
  EXPORTING IT_FIELDCATALOG = LF
  IMPORTING EP_TABLE = VR.

  ASSIGN VR->* TO <P>.
  SELECT * FROM (TABN) APPENDING TABLE <P>.

  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
       EXPORTING
            I_BUFFER_ACTIVE         = ' '
            I_CALLBACK_PROGRAM      = SY-REPID
            I_STRUCTURE_NAME        = TABN
            I_SAVE                  = 'X'
       IMPORTING
            E_EXIT_CAUSED_BY_CALLER = G_EXIT_CAUSED_BY_CALLER
            ES_EXIT_CAUSED_BY_USER  = GS_EXIT_CAUSED_BY_USER
       TABLES
            T_OUTTAB                = <P>
       EXCEPTIONS
            PROGRAM_ERROR           = 1
            OTHERS                  = 2.
ELSE.
  WRITE:/ 'Неправильное имя таблицы'.
ENDIF.

Sent

Получилось, пасиб. А подскажи еще: как перед выводом таблицы сделать экран с запросом имени таблицы?

artyom

parameter blablabla like RSRD1-TBMA_VAL (взял из se11)

OlegDm

Sent написал(а):

Получилось, пасиб. А подскажи еще: как перед выводом таблицы сделать экран с запросом имени таблицы?

См. мой пост выше.

EGF

Sent написал(а):

Получилось, пасиб. А подскажи еще: как перед выводом таблицы сделать экран с запросом имени таблицы?

Может, сразу целиком свою задачу выложите, а добрые дяди и тёти с форума её быстренько реализуют.

artyom

Вот за что я уважаю всех своих собеседников по данному форуму, дак это за терпеливость, на каком-нибудь форуме по какому-нибудь PHP давно бы написали что-то типа RTFM или чего то еще... :wink:

EGF

EGF написал(а):

Может, сразу целиком свою задачу выложите, а добрые дяди и тёти с форума её быстренько реализуют.

artyom написал:

Вот за что я уважаю всех своих собеседников по данному форуму, дак это за терпеливость, на каком-нибудь форуме по какому-нибудь PHP давно бы написали что-то типа RTFM или чего то еще... :wink:

Простите, погорячился... Видимо, просто Юрий Тонконог нашёл наконец-то работу!

Правила форума

Вызов первого экрана

Кто сейчас на конференции