FORM append_old_data TABLES pt_data_all
                            pt_package
                      USING value(p_tabix) TYPE i
                            value(p_mch_on)
                            pt_fieldmap TYPE tt_comp_fieldmap
                            pt_kfgs TYPE rsdri_th_sfk
                            p_recnum TYPE i.

  DATA: ls_key1 TYPE cube_key,
        ls_key2 TYPE cube_key,
        ls_kfg TYPE rsdri_s_sfk,
        p_ref TYPE REF TO data,
        ls_fieldmap TYPE comp_fieldmap,
        l_dummy TYPE c.

  DATA: BEGIN OF ls_data,
          recordmode  TYPE rodmupdmod,
          recno       TYPE sy-tabix,
          /bic/mch_on TYPE /bic/oimch_on,
        END OF ls_data.

  FIELD-SYMBOLS: <fs> TYPE ANY,
                 <fs_to> TYPE ANY,
                 <fs_from> TYPE ANY,
                 <fs_rec> TYPE ANY,
                 <kyf> TYPE ANY.

  CREATE DATA p_ref LIKE LINE OF pt_package.
  ASSIGN p_ref->* TO <fs_rec>.
  CHECK sy-subrc = 0.
  READ TABLE pt_data_all ASSIGNING <fs> INDEX p_tabix.
  CHECK sy-subrc = 0.
  MOVE-CORRESPONDING <fs> TO ls_key1.
  DO.
    READ TABLE pt_data_all ASSIGNING <fs> INDEX p_tabix.
    IF sy-subrc <> 0.
      EXIT.
    ENDIF.
    MOVE-CORRESPONDING <fs> TO ls_key2.
    IF ls_key1 <> ls_key2.
      EXIT.
    ENDIF.
    CLEAR <fs_rec>.

*       МЕНЯЕМ ЗНАК У ВСЕХ ПОКАЗАТЕЛЕЙ
    LOOP AT pt_kfgs INTO ls_kfg.
      ASSIGN COMPONENT ls_kfg-kyfnm OF STRUCTURE <fs> TO <kyf>.
      CHECK sy-subrc = 0.
      <kyf> = - <kyf>.
    ENDLOOP.
*       MOVE-CORRESPONDING l_s_data -> ls_rec2
    LOOP AT pt_fieldmap INTO ls_fieldmap.
      ASSIGN COMPONENT ls_fieldmap-name_from OF STRUCTURE <fs>
             TO <fs_from>.
      IF sy-subrc <> 0.
        MESSAGE e799(rsm1) WITH text-i13 ls_fieldmap-name_from
                                space space
          INTO l_dummy.
        RETURN.
      ENDIF.
      ASSIGN COMPONENT ls_fieldmap-name_to OF STRUCTURE <fs_rec>
             TO <fs_to>.
      IF sy-subrc <> 0.
        MESSAGE e799(rsm1) WITH text-i12 ls_fieldmap-name_to
                                space space
          INTO l_dummy.
        RETURN.
      ENDIF.
      <fs_to> = <fs_from>.
    ENDLOOP.
   ls_data-recordmode = 'X'.
    ADD 1 TO p_recnum.
    ls_data-recno = p_recnum.
    ls_data-/bic/mch_on = p_mch_on.
    MOVE-CORRESPONDING ls_data TO <fs_rec>.
    APPEND <fs_rec> TO pt_package.
    ADD 1 TO p_tabix.
  ENDDO.

ENDFORM.                    " append_old_data