*"  IMPORTING
*"     VALUE(I_STRUCT_NAME) TYPE  CHAR30
*"     VALUE(I_DATA_FOR_CHECK)
*"     VALUE(I_CONSTANTS) OPTIONAL
*"  EXCEPTIONS
*"      NO_STRUCT_NAME
*"      NO_STRUCT
*"      NO_STRUCT_INFO_F
*"      NO_STRUCT_INFO_K
*"      INTERNAL_ERR
*"      NO_KEY
*"      NOT_EXISTS
*"      ERR_IN_LOG
*"----------------------------------------------------------------------

  IF i_struct_name IS INITIAL.
    RAISE  no_struct_name.
  ENDIF.

  IF struct_name1 NE i_struct_name.
    struct_name1 = i_struct_name.

* Заполняем таблицу с технич. информацией о полях струк-ры i_struct_name
    CLEAR t_fields[].
    CALL FUNCTION 'DD_TABL_GET'
     " читаем поля структуры в таблицу
      EXPORTING
        tabl_name      = i_struct_name
        withtext       = 'X'
      TABLES
        dd03p_tab_a    = t_fields
      EXCEPTIONS
        access_failure = 1
        OTHERS         = 2.

    IF sy-subrc = 0. " информ. по полям прочитана в таблицу
      IF t_fields[] IS INITIAL. " нет записей в таблице
        CLEAR struct_name1.
        RAISE  no_struct.
      ELSE.
        " заполняем кратк.информ.о полях структуры i_struct_name
        CLEAR t_fields1[].
        LOOP AT t_fields
        WHERE checktable NE space AND fieldname NE 'MANDT'.
          MOVE-CORRESPONDING t_fields TO wa_field1.
          APPEND wa_field1 TO t_fields1.
        ENDLOOP.
        CLEAR t_fields[].
      ENDIF.

    ELSE. " тех.инф. о полях структуры i_struct_name не прочитана
      CLEAR struct_name1.
      RAISE  no_struct_info_f.
    ENDIF.
  ENDIF. " табл.с информ.о полях структуры i_struct_name заполнена

  IF t_fields1[] IS NOT INITIAL. " в струк-ре есть поля с провероч.табл.

* Цикл по полям структуры i_struct_name
    CLEAR fl_err.
    ASSIGN i_data_for_check TO <struct_data>.
    ASSIGN i_constants      TO <struct_const>.

    LOOP AT t_fields1 INTO wa_field1.
      ASSIGN COMPONENT wa_field1-fieldname OF STRUCTURE <struct_data>
        TO <field0>.

      IF sy-subrc = 0 AND     " в i_data_for_check есть такое поле
      <field0> IS NOT INITIAL. " поле заполнено

          CLEAR t_keys_check[].
          CALL FUNCTION 'DD_TBFK_GET'
            " читаем ключи для обр-я в проверочн.табл. в таблицу
            EXPORTING
              fieldname     = wa_field1-fieldname
              tabl_name     = i_struct_name
            TABLES
              dd05m_tab_a   = t_keys_check
            EXCEPTIONS
              illegal_value = 1
              OTHERS        = 2.

        IF sy-subrc = 0. " ключи для обр-я в провероч.табл.прочитаны

          READ TABLE t_keys_check INTO wa_key
            WITH KEY forkey = wa_field1-fieldname.

          IF sy-subrc = 0. " поле, к-е надо читать из провер.табл.найд.
            s_field      = wa_key-checkfield.

            CLEAR s_conditions[].
            LOOP AT t_keys_check INTO wa_key.

              IF wa_key-forkey NE 'MANDT'.
                " формирование условия для динамического select
                s_table = wa_key-checktable.
                s_cond  = wa_key-checkfield.

                IF wa_key-datatype = 'DATS'.
                 CONCATENATE s_cond '>=' INTO s_cond SEPARATED BY space.
                ELSE.
                 CONCATENATE s_cond '='  INTO s_cond SEPARATED BY space.
                ENDIF.

                CASE wa_key-fortable.

                  WHEN i_struct_name.
                    IF wa_key-forkey NE wa_field1-fieldname.
                      CLEAR fl_comp.
                      ASSIGN COMPONENT wa_key-forkey
                        OF STRUCTURE <struct_data> TO <field1>.
                      IF sy-subrc = 0. " в i_data_for_check есть поле
                        fl_comp = 'X'.
                      ELSE.
                        ASSIGN COMPONENT  wa_key-forkey OF STRUCTURE
                          <struct_const> TO <field1>.
                        IF sy-subrc = 0. " в i_constants есть такое поле
                          fl_comp = 'X'.
                        ENDIF.
                      ENDIF.
                      IF fl_comp = 'X'. " есть такое поле во вход.дан.
                        CONCATENATE s_cond '''' <field1> ''''
                          INTO s_cond.
                        APPEND s_cond TO s_conditions.
                      ELSE.
                        RAISE  no_key.
                      ENDIF.
                    ELSE.
                      CONCATENATE s_cond '''' <field0> '''' INTO s_cond.
                      APPEND s_cond TO s_conditions.
                    ENDIF.

                  WHEN 'SY' OR 'SYST'. " данные берутся из струк-ры SYST
                    ASSIGN COMPONENT wa_key-forkey OF STRUCTURE syst
                      TO <field1>.
                    IF sy-subrc = 0. " в SYST есть поле wa_key-forkey
                      CONCATENATE s_cond '''' <field1> '''' INTO s_cond.
                      APPEND s_cond TO s_conditions.
                    ELSE.
                      RAISE  internal_err.
                    ENDIF.

                  WHEN '*'. " поле - родовой ключ

                  WHEN OTHERS.
                    IF wa_key-fortable+0(1) NE ''''.
                      " полю wa_field1-fieldname не присв. постоян. зн-е
                      CLEAR fl_comp.
                      ASSIGN COMPONENT wa_key-forkey OF STRUCTURE
                        <struct_const> TO <field1>.
                      IF sy-subrc = 0. " в i_constants есть такое поле
                        fl_comp = 'X'.
                      ELSE.
                        ASSIGN COMPONENT wa_key-forkey OF STRUCTURE
                          <struct_data> TO <field1>.
                        IF sy-subrc = 0. " в i_data_for_check есть поле
                          fl_comp = 'X'.
                        ENDIF.
                      ENDIF.
                      IF fl_comp = 'X'. " есть такое поле во вход.дан.
                        CONCATENATE s_cond '''' <field1> ''''
                          INTO s_cond.
                        APPEND s_cond TO s_conditions.
                      ELSE.
                        RAISE no_key.
                      ENDIF.
                    ELSE.
                      " полю wa_field1-fieldname присв-ся постоян. зн-е
                      CONCATENATE s_cond wa_key-fortable INTO s_cond.
                      APPEND s_cond TO s_conditions.
                    ENDIF.
                ENDCASE.
              ENDIF.
            ENDLOOP.

            IF s_conditions[] IS NOT INITIAL. " логич-е усл-я сформир-ны
              LOOP AT s_conditions INTO s_cond FROM 2.
                CONCATENATE 'AND' s_cond INTO s_cond SEPARATED BY space.
                MODIFY s_conditions FROM s_cond.
              ENDLOOP.

              CREATE DATA wa_field TYPE (wa_field1-rollname).
              ASSIGN wa_field->* TO <field1>.

              SELECT SINGLE (s_field)
              INTO <field1>
              FROM (s_table)
              WHERE (s_conditions).

              IF sy-subrc NE 0. " зн-е не найдено в провероч.таблице
                MESSAGE e001 WITH wa_field1-scrtext_l <field0>
                  INTO dummy_msg.
                  fl_err = 'X'.
                  "Заполнение протокола
              ENDIF.
            ENDIF.
          ELSE. " поле, к-е надо читать из провероч.табл. не найдено
            RAISE no_key.
          ENDIF.
        ELSE. " тех.инф. о ключах провероч.табл.не прочитана
          RAISE  no_struct_info_k.
        ENDIF.
      ENDIF.
    ENDLOOP.
    IF fl_err = 'X'. " зн-я некот.полей не найдены,
      RAISE err_in_log.
    ENDIF.
  ENDIF.

DATA: l_eleminfo  TYPE REF TO cl_abap_elemdescr,
      l_domain    TYPE abap_helpid,
      it_values   TYPE ddfixvalues.

l_eleminfo ?= cl_abap_elemdescr=>describe_by_data( field ).
l_domain  = l_eleminfo->help_id.
it_values = l_eleminfo->get_ddic_fixed_values( ).

 
data: lt_return type bapiret2_t,
        lo_msg_list type ref to IF_RECA_MESSAGE_LIST.

  lo_msg_list = CF_RECA_MESSAGE_LIST=>CREATE( ).

  CL_RECA_CUST_CHECK_SERVICES=>CHECK_STRUCT_DATA( IS_STRUCT  = cs_data_card
                                                  IO_MSGLIST = lo_msg_list ).

  if lo_msg_list->HAS_MESSAGES_OF_MSGTY( 'E' ) eq abap_true.
    lo_msg_list->GET_LIST_AS_BAPIRET( IMPORTING ET_LIST = lt_return ).
  endif.