одинарный клик в ALV GRID

Primat

Подскажите пожалуйста как обработать одинарный клик в ALV GRID.

sy-uname

Primat написал(а):

Подскажите пожалуйста как обработать одинарный клик в ALV GRID.

А разве что то происходит при одинарном клике? Вроде бы никаких событий данное действие не вызывает. Равно как и смена фокуса поля, переход между полями по табу и т.п. навигация.

Primat

Вот я и не чего не нашел по этому поводу. Может существует обход этой ситуации?(че-то добавить, кроме кнопок и галок).Было бы хорошо если существовало такое событие.

111

Смотря какой ALV Grid (их несколько классов существует).
Одинарный клик срабатывает у полей, для которых установлена опция HOTSPOT или LINK (если используется CL_SALV_TABLE).

Primat

set_table_for_first_display

John Doe

Немного кода:

Code:

CLASS LCL_HANDLER_RECEIVING DEFINITION.
  PUBLIC SECTION.
    METHODS: HANDLE_DELAYED_CHANGED_SEL_CB
               FOR EVENT DELAYED_CHANGED_SEL_CALLBACK
               OF CL_GUI_ALV_GRID.

ENDCLASS.

DATA: G_HANDLER TYPE REF TO LCL_HANDLER_RECEIVING.   " Event handler
CLASS LCL_HANDLER_RECEIVING IMPLEMENTATION.
  METHOD HANDLE_DELAYED_CHANGED_SEL_CB.
    PERFORM SELECTION_CHANGED.
  ENDMETHOD.

ENDCLASS.

Code:

    PERFORM CHECK_FRONTEND_TYPE IN PROGRAM SAPFSSOA
             USING GP_FRONTEND.
    IF GP_FRONTEND <> 'ITS'.
      SET HANDLER G_HANDLER->HANDLE_DELAYED_CHANGED_SEL_CB
                     FOR PROJ_GRID.
* Activate delayed event for preview
      CALL METHOD PROJ_GRID->REGISTER_DELAYED_EVENT
         EXPORTING
            I_EVENT_ID = CL_GUI_ALV_GRID=>MC_EVT_DELAYED_CHANGE_SELECT.
    ENDIF.

Работает вместо дабл-клика - в смысле регистрировать либо дабл-клик, либо это событие.

Azik

Чето мне кажется вы усложняете, вот же есть простой вариант.

CLASS lcl_event_handler DEFINITION .
PUBLIC SECTION .
METHODS:
*Hotspot click control
handle_hotspot_click
FOR EVENT hotspot_click OF cl_gui_alv_grid
IMPORTING e_row_id e_column_id es_row_no .
PRIVATE SECTION.
ENDCLASS.

CLASS lcl_event_handler IMPLEMENTATION .
*Handle Hotspot Click
METHOD handle_hotspot_click .
PERFORM handle_hotspot_click USING e_row_id e_column_id es_row_no .
ENDMETHOD .
ENDCLASS .

John Doe

Использование хотспот - не спортивно

Да и внешний вид портиться, на мой взгляд.

Primat

John Doe написал:

Немного кода:

Code:

CLASS LCL_HANDLER_RECEIVING DEFINITION.
  PUBLIC SECTION.
    METHODS: HANDLE_DELAYED_CHANGED_SEL_CB
               FOR EVENT DELAYED_CHANGED_SEL_CALLBACK
               OF CL_GUI_ALV_GRID.

ENDCLASS.

DATA: G_HANDLER TYPE REF TO LCL_HANDLER_RECEIVING.   " Event handler
CLASS LCL_HANDLER_RECEIVING IMPLEMENTATION.
  METHOD HANDLE_DELAYED_CHANGED_SEL_CB.
    PERFORM SELECTION_CHANGED.
  ENDMETHOD.

ENDCLASS.

Code:

    PERFORM CHECK_FRONTEND_TYPE IN PROGRAM SAPFSSOA
             USING GP_FRONTEND.
    IF GP_FRONTEND <> 'ITS'.
      SET HANDLER G_HANDLER->HANDLE_DELAYED_CHANGED_SEL_CB
                     FOR PROJ_GRID.
* Activate delayed event for preview
      CALL METHOD PROJ_GRID->REGISTER_DELAYED_EVENT
         EXPORTING
            I_EVENT_ID = CL_GUI_ALV_GRID=>MC_EVT_DELAYED_CHANGE_SELECT.
    ENDIF.

Работает вместо дабл-клика - в смысле регистрировать либо дабл-клик, либо это событие.

А что еще нужно дописать чтоб она заработала (кроме set handler g_verifier->HANDLE_DELAYED_CHANGED_SEL_CB for g_grid.
) наверное что-то нужно дописать в филдкаталоге? Можно по подробней как пользоваться методом.

Primat

Azik написал:

Чето мне кажется вы усложняете, вот же есть простой вариант.

CLASS lcl_event_handler DEFINITION .
PUBLIC SECTION .
METHODS:
*Hotspot click control
handle_hotspot_click
FOR EVENT hotspot_click OF cl_gui_alv_grid
IMPORTING e_row_id e_column_id es_row_no .
PRIVATE SECTION.
ENDCLASS.

CLASS lcl_event_handler IMPLEMENTATION .
*Handle Hotspot Click
METHOD handle_hotspot_click .
PERFORM handle_hotspot_click USING e_row_id e_column_id es_row_no .
ENDMETHOD .
ENDCLASS .

+ в филд каталоге hs_fieldcat-HOTSPOT = 'X'
(дополнения для не стакливавшихся с методом)

John Doe

В филдкаталоге ничего прописывать не надо. Метод срабатывает при смене фокуса на строчке, но с небольшой задержкой. Метод взаимоисключаем с методом дабл-клик.

Primat

Благодарю все получилось.
Буду пользоваться hotspot.
HANDLE_DELAYED_CHANGED_SEL_CB напрягает 1,5 сек простоя.

printfalex

Задержку можно уменьшить.
Она задаётся с помощью вызова метода SET_DELAY_CHANGE_SELECTION. Одна проблема - он protected. Но проблема решаемая.
Можно создать класс наследник от cl_gui_alv_grid, в нём создать метод вызывающий внутри себя SET_DELAY_CHANGE_SELECTION с указанием времени задержки.

Вот примерчик из интернета:

Code:

*----------------------------------------------------------------------*
CLASS lcl_alv_wrapper DEFINITION INHERITING FROM cl_gui_alv_grid.
  PUBLIC SECTION.
    METHODS : constructor,
              set_delay_time,
              click FOR EVENT delayed_changed_sel_callback OF cl_gui_alv_grid.
ENDCLASS.                    "lcl_alv_wrapper DEFINITION
 
*----------------------------------------------------------------------*
CLASS lcl_alv_wrapper IMPLEMENTATION.
  METHOD constructor.
    super->constructor( i_parent = cl_gui_container=>default_screen ).
    SET HANDLER me->click FOR ALL INSTANCES.
  ENDMETHOD.                    "constructor
  METHOD set_delay_time.
    me->set_delay_change_selection( 10 ).
  ENDMETHOD.                    "set_delay_time
  METHOD click.
    MESSAGE 'Hi' TYPE 'I'.
  ENDMETHOD.                    "click
ENDCLASS.                    "lcl_alv_wrapper IMPLEMENTATION
 
DATA : grid    TYPE REF TO lcl_alv_wrapper,
       TABLE   TYPE STANDARD TABLE OF makt.
 
 
PARAMETER DUMMY.
 
AT SELECTION-SCREEN OUTPUT.
 
  CREATE OBJECT grid.
 
  SELECT * FROM makt INTO CORRESPONDING FIELDS OF TABLE TABLE UP TO 27 ROWS.
 
  grid->set_table_for_first_display( EXPORTING i_structure_name = 'MAKT'
                                      CHANGING it_outtab       = TABLE ).
  grid->register_delayed_event( i_event_id = cl_gui_alv_grid=>mc_evt_delayed_change_select ).
  grid->set_delay_time( ).

camelotka

John Doe написал:

Использование хотспот - не спортивно

Да и внешний вид портиться, на мой взгляд.

Не усложняйте, HOTSPOT прекрасно и стабильно работает...
SAP и красивый интерфейс вещи не совместимые

Удав

Задержка с ответом явно больше 1,5 секунд

Правила форума

одинарный клик в ALV GRID

Кто сейчас на конференции