Проверьте себя

T

Ну и CALL DIALOG видимо тоже на отдельном стеке живёт..

Сергей Королев

А вот еще проверка знаний для пятого класса

К примеру, в функциональном модуле захотелось вызвать подпрограмму (FORM). Как сделать так, чтобы параметры функционального модуля были доступны в этой подпрограмме? (передача параметров в подпрограмму не рассматривается).

T

Без использования глобализации параметров и без глобальных данных?

Сергей Королев

Вот-вот, я как раз про глобализацию параметров

Раньше никогда этим не пользовался

nicky555

Сейчас угадаю...

Речь идет о следующем:
DATA: BEGIN OF COMMON PART <x> ... :?:

Прикольная штучка - пользовался пару раз

Сергей Королев

Нет, там на закладке свойств функционального модуля справа внизу есть флажок "Глобально". В результате параметры функции будут доступны в подпрограммах (но действительны будут только на время вызова функции).

Гость

nicky555 написал:

Речь идет о следующем:
DATA: BEGIN OF COMMON PART <x> ... :?:

Внутри одной группы функций это не требуется. Эта штука между програмами работает. Причём все равно её надо определять в глобальных данных программ.

То, чего хотел г.Королёв уже прояснилось

А чем там всё-таки в основных средствах вызывается отчёт/модуль?

T

Это я был вверху...

EGF

nicky555 написал:

ну так вот...
есть обработка ОС (AS01-AS03),
есть возможность вызвать оттуда свою программу (отчет, диалог),
есть расписанная всеми с ног до головы возможность получить данные контекста через память (через field-symbols).
Соответственно, пишу свою вызываемую программу, ожидаю, используя Field-symbols, получить данные контекста транзакций ОС.
... И ничего не выходит :wink:

Вопрос: как реализован вызов моей программы?

А можно я тоже подключусь? Если я правильно понял задачу, то решение, видимо, заключается в том, что доступ с помощью field-symbols возможен к переменным вызывающих программ, которые загружены в ту же Internal Session, что и вызываемая программа. В случае использования SUBMIT создаётся новая Internal Session (впрочем, как и при CALL FUNCTION '...' STARTING NEW TASK), в случае же использования PERFORM или CALL FUNCTION '...' новая сессия не создаётся.

Code:

REPORT  zef_test3.
DATA:
  g_text(3) VALUE 'SAP'
.
SUBMIT zef_test5 AND RETURN.
PERFORM foreign_access(zef_test5).



REPORT zef_test5.
TYPES:
  t_text TYPE c LENGTH 3
.
PERFORM foreign_access.

FORM foreign_access.

  FIELD-SYMBOLS:
    <g_text> TYPE t_text
  .
  ASSIGN ('(ZEF_TEST3)G_TEXT') TO <g_text>.
  IF sy-subrc = 0.
    WRITE <g_text>.
  ENDIF.
ENDFORM.                    "foreign_access

В результате будет выведена одна строка.

T

EGF написал(а):

В случае использования SUBMIT создаётся новая Internal Session (впрочем, как и при CALL FUNCTION '...' STARTING NEW TASK)

Да, и при CALL TRANSACTION и CALL DIALOG тоже..
Причём интернал сессий может быть не более 9-ти..

nicky555

Сергей Королев написал:

Нет, там на закладке свойств функционального модуля справа внизу есть флажок "Глобально". В результате параметры функции будут доступны в подпрограммах (но действительны будут только на время вызова функции).

А я-то подумал о разных программах... Внутри группы функций вопрос не очень интересен...

2EGF: совершенно верно.
Тот вызов, о котором я упоминал есть REP-REP интерфейс, реализован, в зависимости от настройки, через SUBMIT или CALL TRANSACTION.
То бишь, стартует новую Internal session. Обмен же данными между ними (смотрим справку), только через Export/Import ... memory...

Сергей Королев

Засада, был уверен, что при SUBMIT'е работает ASSIGN, но видимо просто вызывал подпрограмму через PERFORM f IN PROGRAM p.

EGF

На форуме SAPfans.com есть интересный пример, откопанный в недрах стандартного кода САП.

Code:

  IF 'Z' < '9'. 
    HIGHVALUE = '9999999999999999999999'. 
  ELSE. 
    HIGHVALUE = 'ZZZZZZZZZZZZZZZZZZZZZZ'. 
  ENDIF.

Для чего нужен этот код? Правильного ответа у меня нет, но наиболее вероятные версии есть здесь.

EGF

Недавно наткнулся на общеизвестную, но не совсем очевидную вещь.

Code:

CONSTANTS:
  gc_matnr  TYPE matnr VALUE '000000000000002492',
  gc_matnr1 TYPE matnr VALUE '000000000000002493'
.
DATA:
  gs_head  TYPE bapimathead,
  gs_mara  TYPE bapi_mara,
  gs_marax TYPE bapi_marax,
  g_bismt  TYPE bismt         "Старый номер материала
.
CALL FUNCTION 'ENQUEUE_EMMARAE'
  EXPORTING
    matnr          = gc_matnr
  EXCEPTIONS
    foreign_lock   = 1
    system_failure = 2
    OTHERS         = 3.
CHECK sy-subrc = 0.

CALL FUNCTION 'ENQUEUE_EMMARAE'
  EXPORTING
    matnr          = gc_matnr1
  EXCEPTIONS
    foreign_lock   = 1
    system_failure = 2
    OTHERS         = 3.
CHECK sy-subrc = 0.

gs_head-material = gc_matnr.
gs_mara-old_mat_no = 'XXX'.
gs_marax-old_mat_no = 'X'.

CALL FUNCTION 'BAPI_MATERIAL_SAVEDATA'
  EXPORTING
    headdata    = gs_head
    clientdata  = gs_mara
    clientdatax = gs_marax.

COMMIT WORK.

CALL FUNCTION 'ENQUEUE_EMMARAE'
  EXPORTING
    matnr          = gc_matnr
  EXCEPTIONS
    foreign_lock   = 1
    system_failure = 2
    OTHERS         = 3.
WRITE sy-subrc.

CALL FUNCTION 'ENQUEUE_EMMARAE'
  EXPORTING
    matnr          = gc_matnr1
  EXCEPTIONS
    foreign_lock   = 1
    system_failure = 2
    OTHERS         = 3.
WRITE / sy-subrc.

SELECT SINGLE bismt
  INTO g_bismt
  FROM mara
  WHERE matnr = gc_matnr.
WRITE / g_bismt.

Вопрос: что будет на экране, если материалы gc_matnr и gc_matnr1 существуют в системе?

EGF

Немного задержался с ответом...
На экране будет вот что

Code:

    0 
    0 
XXX   

Общеизвестный, но неочевидный факт заключается в том, что после комманды COMMIT WORK будут сняты все блокировки, установленные ранее в программе с параметром
_SCOPE = '2', который устанавливается в это значение по умолчанию.
Я долго удивлялся, куда же девались мои блокировки.

Правила форума

Проверьте себя

Кто сейчас на конференции