*******************************************************************
* В результате выполнения должен получиться проект со структурой
*
*  200-A
*     +- 2050
*     |  +- 2050-1
*     |  +- 2050-2
*     |  +- 2050-3
*     +- 2060
*     +- 2070
*
*  !!! Определение проекта (200-A) должно быть создано заранее !!!
*
********************************************************************
report zpm_x_wbs_bapi_create.

data: gs_def        type bapi_project_definition,
      gs_def_upd    type bapi_project_definition_up,
      gt_method     type table of bapi_method_project with header line,
      gt_wbs        type table of bapi_wbs_element with header line,
      gt_message    type table of bapi_meth_message with header line,
      gt_wbs_hier   type table of bapi_wbs_hierarchie with header line.

* Макросы
define append_method.
  clear gt_method.
  gt_method-refnumber  = &1.
  gt_method-objecttype = &2.
  gt_method-method     = &3.
  gt_method-objectkey  = &4.
  append gt_method.
end-of-definition.

define append_wbs.
  clear gt_wbs.
  gt_wbs-project_definition = &1.
  gt_wbs-wbs_element        = &2.
  gt_wbs-description        = &3.
  append gt_wbs.
end-of-definition.

define append_hier.
  clear gt_wbs_hier.
  gt_wbs_hier-project_definition = &1.
  gt_wbs_hier-wbs_element        = &2.
  gt_wbs_hier-up                 = &3.
  gt_wbs_hier-down               = &4.
  gt_wbs_hier-left               = &5.
  gt_wbs_hier-right              = &6.
  append gt_wbs_hier.
end-of-definition.


* Project definition
gs_def-project_definition = '200-A'.

* Method
append_method: '000001' 'WBS-ELEMENT'   'CREATE' '2050',
               '000002' 'WBS-ELEMENT'   'CREATE' '2050-1',
               '000003' 'WBS-ELEMENT'   'CREATE' '2050-2',
               '000004' 'WBS-ELEMENT'   'CREATE' '2050-3',
               '000005' 'WBS-ELEMENT'   'CREATE' '2060',
               '000006' 'WBS-ELEMENT'   'CREATE' '2070',
               space    'WBS-HIERARCHY' 'CREATE' space,
               space    space           'SAVE'   space.

* WBS
append_wbs: '200-A' '2050'   'СПП элемент 2050',
            '200-A' '2050-1' 'СПП элемент 2050-1',
            '200-A' '2050-2' 'СПП элемент 2050-2',
            '200-A' '2050-3' 'СПП элемент 2050-3',
            '200-A' '2060'   'СПП элемент 2060',
            '200-A' '2070'   'СПП элемент 2070'.

* Hierarchy
*            PD      WBS      UP     Down     Left     Right
append_hier: '200-A' '2050'   space  '2050-1' space    '2060',
             '200-A' '2060'   space   space   '2050'   '2070',
             '200-A' '2070'   space   space   '2060'   space,
             '200-A' '2050-1' '2050'  space   space    '2050-2',
             '200-A' '2050-2' '2050'  space   '2050-1' '2050-3',
             '200-A' '2050-3' '2050'  space   '2050-2' space.

call function 'BAPI_PROJECT_MAINTAIN'
  exporting
    i_project_definition     = gs_def
    i_project_definition_upd = gs_def_upd
  tables
    i_method_project         = gt_method
    i_wbs_element_table      = gt_wbs
    i_wbs_hierarchie_table   = gt_wbs_hier
    e_message_table          = gt_message.

if gt_message[] is initial.
  call function 'BAPI_TRANSACTION_COMMIT'
    exporting
      wait = 'X'.
endif.