Вывод опреленных столбцов в GRID (cl_gui_alv_grid)

DaniKz

grid1 TYPE REF TO cl_gui_alv_grid

Есть какаето таблица "ТАБ". При выводе ГРИДА вылазеют все столбцы таблицы, как сделать так чтобы были видны только определенные столбцы данной таблицы. К примеру 1-2 столбца.

T

В каталоге полей укажи для ненужных столбцов NO_OUT = 'X'
Или вообще удали их из каталога полей
Или сохрани вариант по умолчанию и вызывай его при создании

Гость

А можно немного по подробнее

OlegDm

Anonymous написал(а):

А можно немного по подробнее

Вот например, вывыдится первые 4 столбца внутр.таблицы:

Code:

PROGRAM ztest.

tables: t001l.


data: ok_code like sy-ucomm,
      gt_t001l type table of t001l,
      g_container type scrfname value 'GRID',
      l_grid type ref to cl_gui_alv_grid,
      g_custom_container type ref to cl_gui_custom_container.

data:
      gt_fieldcat type lvc_t_fcat with header line.


start-of-selection.
  select * into table gt_t001l from t001l.


end-of-selection.

CALL SCREEN 100.

*---------------------------------------------------------------------*
*       MODULE PBO OUTPUT                                             *
*---------------------------------------------------------------------*
module pbo output.
  set pf-status 'MAIN100'.
  if g_custom_container is initial.
    create object g_custom_container
           exporting container_name = g_container.
    create object l_grid
           exporting i_parent = g_custom_container.


    perform create_fieldcatalog.

    call method l_grid->set_table_for_first_display
         changing   it_fieldcatalog = gt_fieldcat[]
                          it_outtab = gt_t001l.
  endif.
endmodule.

*---------------------------------------------------------------------*
*       MODULE PAI INPUT                                              *
*---------------------------------------------------------------------*
module pai input.
  call method cl_gui_cfw=>dispatch.
  case ok_code.
    when 'EXIT'.
      perform exit_program.
    when others.
*     do nothing
  endcase.
  clear ok_code.
endmodule.

*---------------------------------------------------------------------*
*       form exit_program                                             *
*---------------------------------------------------------------------*
form exit_program.
  call method g_custom_container->free.
  call method cl_gui_cfw=>flush.
  leave program.
endform.

*&---------------------------------------------------------------------*
*&      Form  create_fc
*&---------------------------------------------------------------------*
FORM create_fieldcatalog.
  call function 'LVC_FIELDCATALOG_MERGE'
       exporting
            i_structure_name = 'T001L'
       changing
            ct_fieldcat      = gt_fieldcat[].

  loop at gt_fieldcat.
    if sy-tabix > 5.
      gt_fieldcat-no_out = 'X'.
      modify gt_fieldcat index sy-tabix.
    endif.
  endloop.

ENDFORM.                    " create_fieldcatalog

ВН

а есть еще один способ.
я его часто применяю в ALV.

Запускаешь программу, создаешь ALV-вариант,
где можешь скрыть не нужные столбцы, отфильтров,
и т.д. и т.п.
Обзываешь его, скажем 'Z1'
А потом в программе уже указываешь - вызов с вариантом.

Преимущество этого способа в том, что
ты как бы определяешь вариант по умолчанию.
Если впоследствие придется добавить/убрать столбец,
то не нужно менять программу. Пользователь
сам сможет изменить вариант и сохранить его

T

ВН написал(а):

Обзываешь его, скажем 'Z1'
А потом в программе уже указываешь - вызов с вариантом.

Только не нужно зашивать имя варианта в программу!
Используй:

REUSE_ALV_VARIANT_DEFAULT_GET
или
LVC_VARIANT_DEFAULT_GET

Он вернёт тот вариант, который настроен по-умолчанию для пользователя или для всех (смотря как сохранить, какие права дать пользователю для работы с вариантами и т.п.)

Code:

  
  GS_VARIANT-REPORT = sy-repid.
  GS_VARIANT-HANDLE = sy-dynnr.

  CALL FUNCTION 'REUSE_ALV_VARIANT_DEFAULT_GET'
       EXPORTING
            I_SAVE        = 'A'
       CHANGING
            CS_VARIANT    = GS_VARIANT
       EXCEPTIONS
            WRONG_INPUT   = 1
            NOT_FOUND     = 2
            PROGRAM_ERROR = 3
            OTHERS        = 4.

ВН

ну да, Толян

можно и так, так - правильнее

OlegDm

Мы тоже зачастую именно вариантами разруливаем. Есть например отчет по сбыту - накидали туда полей немерено - насоздавали сами какие-то варианты, плюс юзеры под себя наделали - все рады, все довольны - все-таки ALV - классная штука

DaniKz

Всем спасибо за ответ.
И еще один вопрос.
А можно ли задать структуру ГРИДА как у внутренней таблицы созданной например из нескольких таблиц?

OlegDm

ВН написал(а):

ну да, Толян

можно и так, так - правильнее

имхо, еще и на селекц.экран вывести выбор варианта стоит для полного щастья

T

OlegDm написал(а):

ВН написал(а):

ну да, Толян

можно и так, так - правильнее

имхо, еще и на селекц.экран вывести выбор варианта стоит для полного щастья

А для этого случая не забыть про LVC_VARIANT_F4, чтобы выбор был вменяемый

OlegDm

DaniKz написал(а):

Всем спасибо за ответ.
И еще один вопрос.
А можно ли задать структуру ГРИДА как у внутренней таблицы созданной например из нескольких таблиц?

Был разговор недавно:
http://www.sapboard.ru/forum/viewtopic ... A%F3%F0%F1

мое мнение - создай структуру в словаре и пользуйся на здоровье.

EGF

T написал:

В каталоге полей укажи для ненужных столбцов NO_OUT = 'X'

Можно также использовать TECH = 'X', тогда поля не будет видно в диалоге изменения варианта отображения.

Salas

Цитата:

Запускаешь программу, создаешь ALV-вариант,
где можешь скрыть не нужные столбцы, отфильтров

Простите за глупый вопрос, а как содать ALV-вариаант?

OlegDm

Salas написал(а):

Цитата:

Запускаешь программу, создаешь ALV-вариант,
где можешь скрыть не нужные столбцы, отфильтров

Простите за глупый вопрос, а как содать ALV-вариаант?

надо передать в метод set_table_for_first_display
структуру is_variant:

Code:

...
data: gs_variant type disvariant. 
...
g_repid = sy-repid.
gs_variant-report = g_repid.
gs_variant-variant = '<ВариантПоУмолчанию>'.
...
    call method grid1->set_table_for_first_display
         exporting i_structure_name = 'BlaBlaBla'
                   is_variant       = gs_variant
                   i_save           = 'A'
...
   

Правила форума

Вывод опреленных столбцов в GRID (cl_gui_alv_grid)

Кто сейчас на конференции