REPORT  zpm_BAPI_MATERIAL_SAVEDATA.

tables: mara,
        mbew.

data: headdata       type BAPIMATHEAD,
      valuationdata  type BAPI_MBEW,
      valuationdatax type BAPI_MBEWX,
      plantdata      type BAPI_MARC,
      plantdatax     type BAPI_MARCX.

data: mtart type mtart,
      mbrsh type mbrsh.

data: return type BAPIRET2,
      RETURNMESSAGES type BAPI_MATRETURN2 occurs 0 with header line,
      error_occured.


parameters: matnr type matnr,   " Материал
            plant type WERKS_D, " Примем, что уровень оценки = Завод
            zplp1 type DZPLP1,  " Новая плановая цена
            zpld1 type DZPLD1.  " Действительно с даты

end-of-selection.

  select single mara~mtart mara~mbrsh into (mtart, mbrsh)
           from mbew inner join mara on mara~matnr = mbew~matnr
          where mbew~matnr eq matnr
            and mbew~bwkey eq plant.

  check sy-subrc = 0.

  move: matnr to headdata-material,
        mbrsh to headdata-ind_sector,
        mtart to headdata-matl_type,
        'X'   to headdata-cost_view.

  move: plant to plantdata-plant,
        plant to plantdatax-plant,
        plant to valuationdata-val_area,
        plant to valuationdatax-val_area.

  move: zplp1 to valuationdata-PLNDPRICE1,
        zpld1 to valuationdata-PLNDPRDATE1,
        'X'   to valuationdatax-PLNDPRICE1,
        'X'   to valuationdatax-PLNDPRDATE1.

  CALL FUNCTION 'BAPI_MATERIAL_SAVEDATA'
    EXPORTING
      headdata       = headdata
      PLANTDATA      = PLANTDATA
      PLANTDATAX     = PLANTDATAX
      valuationdata  = valuationdata
      valuationdatax = valuationdatax
    IMPORTING
      return         = return
    TABLES
      RETURNMESSAGES = RETURNMESSAGES.


  loop at RETURNMESSAGES.
    check RETURNMESSAGES-type = 'E' or
          RETURNMESSAGES-type = 'A'.
    error_occured = 'X'.
    exit.
  endloop.

  if error_occured is initial.
    call function 'BAPI_TRANSACTION_COMMIT'  EXPORTING  wait = 'X'.
  else.
    CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
  endif.